Applicare le Funzioni MAX.PIÙ.SE e MIN.PIÙ.SE

Le Funzioni MAX.PIÙ.SE e MIN.PIÙ.SE restituiscono il valore massimo e minimo di una serie di dati, relativamente ad un determinato set di condizioni o criteri. Entrambe le Funzioni sono state introdotte a partire dalla versione 2016 di Excel.

In questo tutorial viene presentata la sintassi e l'applicazione delle due Funzioni MAX.PIÙ.SE e MIN.PIÙ.SE.
Per chi dispone delle versioni Excel precedenti alla 2016 viene illustrato come è possibile ottenere lo stesso risultato applicando le Funzioni SE, MAX e MIN.

Contenuti del tutorial: le Funzioni MAX.PIÙ.SE e MIN.PIÙ.SE

[1] - La Funzione MAX.PIÙ.SE (Sintassi)
[2] - La Funzione MIN.PIÙ.SE (Sintassi)
[3] - Esempio di applicazione delle Funzioni MAX.PIÙ.SE e MIN.PIÙ.SE
[4] - Come applicare più criteri nella ricerca del valore MAX e MIN nelle versioni antecedenti alla 2016
[5] - Osservazioni sull'impostazione matriciale della Formula MAX, MIN e SE - link di approfondimento

La Funzione MAX.PIÙ.SE (sintassi)

La Funzione MAX.PIÙ.SE (nome inglese della Funzione MAXIFS) restituisce  il valore massimo (nell'ambito di determinate celle) specificato da un dato set di condizioni.
Sintassi della Funzione:
=MAX.PIÙ.SE(intervallo_max;intervallo_criteri1;criteri1; [intervallo_criteri2; criteri2]; ...)
Nella quale:
intervallo_max rappresenta l'intervallo di celle da cui verrà estratto il valore più alto
intervallo_criteri1 rappresenta il primo intervallo di celle da valutare
criterio1 definisce il criterio da applicare all'intervallo_criteri1
intervallo_criteri2; criteri2; ... (argomenti facoltativi) rappresentano eventuali successivi intervalli e criteri da valutare

La Funzione MIN.PIÙ.SE (sintassi)

La Funzione MIN.PIÙ.SE (nome inglese della Funzione MINIFS) restituisce  il valore minimo (nell'ambito di determinate celle) specificato da un dato set di condizioni.
Sintassi della Funzione:
=MIN.PIÙ.SE(intervallo_min;intervallo_criteri1;criteri1; [intervallo_criteri2, criteri2]; ...)
Nella quale:
intervallo_min rappresenta l'intervallo di celle da cui verrà estratto il valore più basso
intervallo_criteri1 rappresenta il primo intervallo di celle da valutare
criterio1 definisce il criterio da applicare all'intervallo_criteri1
intervallo_criteri2; criteri2; ... (argomenti facoltativi) rappresentano eventuali successivi intervalli e criteri da valutare.

Esempio di applicazione delle Funzioni MAX.PIÙ.SE e MIN.PIÙ.SE

Quale esempio di applicazione si prenda in considerazione la tabella raffigurata nella successiva immagine, nella quale sono presenti due diversi venditori che operano in due regioni.
Nella cella G3 e G13 si vuole calcolare rispettivamente l'importo più alto e più basso fatturato dal venditore Rossi (I3) nella regione Veneto (J3).

Nella cella G3, è stata imputata la seguente Funzione:
=MAX.PIÙ.SE(E3:E20;C3:C20;I3;D3:D20;J3)
Nella quale E3:E20 rappresenta l'intervallo di valori dal quale estrarre l'importo più alto; C3:C20 è l'intervallo nel quale deve essere applicato il criterio I3 (Rossi); D3:D20 rappresenta il secondo intervallo nel quale applicare il criterio di ricerca J3 (Veneto)
Ovviamente i valori testuali Rossi e Veneto possono essere direttamente definiti nella Funzione inserendoli fra doppi apici:
=MAX.PIÙ.SE(E3:E20;C3:C20;"Rossi";D3:D20;"Veneto")

Con lo stesso criterio, ma con l'obiettivo di restituire il valore più basso. Nella cella G13 è stata imputata la Funzione:
=MIN.PIÙ.SE(E3:E20;C3:C20;I3;D3:D20;J3)
I riferimenti all'intervallo dati da cui restituire il valore più basso, e le colonne su cui applicare i criteri della ricerca, sono gli stessi della precedente Funzione.

Come applicare più criteri nella ricerca del valore MAX e MIN nelle versioni antecedenti alla 2016

Sebbene con una impostazione un po' più complessa, anche nelle versioni di Excel antecedenti alla 2016, è possibile applicare più criteri nella ricerca del valore più alto o più basso.
Con il fine di compare le due diverse impostazioni, viene utilizzato lo stesso esempio precedente. Si tratta pertanto di ricercare il valore di fatturato più alto e più basso di un determinato venditore su una specifica regione.

Ricercare il valore più alto rispetto più condizioni

L'impostazione corretta viene fornita applicando una Funzione di Matrice.
Nella cella G3 è stata applicata la Funzione MAX, con annidate due Funzioni logiche SE (per individuare i valori del venditore e delle regione nelle rispettive colonne di dati C3:C20 e D3:D20)

Nella cella G3 è stata imputata la Formula:
=MAX(SE(C3:C20=I4;SE(D3:D20=J4;E3:E20)))
Attenzione! Si tratta di una comparazione di matrice (C3:C20=I4) di conseguenza per inserire questa formula è necessario utilizzare contemporaneamente la combinazione pulsanti CTRL+SHIF+INVIO
La sintassi dell'espressione nella barra della formula viene evidenziata da Excel fra parentesi graffe proprio per indicarne l'impostazione matriciale.
={MAX(SE(C3:C20=I4;SE(D3:D20=J4;E3:E20)))}

Ricercare il valore più basso rispetto più condizioni

Anche in questo caso, come per il precedente esempio, è stata applicata una Formula per ottenere il valore più basso.
Nella cella G13 è stata imputata la seguente espressione:
=MIN(SE(C3:C20=I4;SE(D3:D20=J4;E3:E20)))
Anche in questo caso per inserire la Funzione è necessario utilizzare il comando CTRL+SHIFT+INVIO

Osservazioni sull'impostazione matriciale della Formula - link di approfondimento

Come anticipato nella parte introduttiva del tutorial, le Funzioni MAX.PIÙ.SE e MIN.PIÙ.SE sono disponibili solo a partire dalla versione 2016 di Excel.
Nelle versioni antecedenti alla 2016 è possibile ricorre ad una Formula di matrice utilizzando le Funzioni MAX. MIN, SE.
La particolarità dell'imputazione della Formula con il comando CTRL+SHIF+INVIO è dovuta alla modalità di inserimento di una Funzione matriciale.
Con la Versione 365, e l'introduzione nel programma di Excel delle matrici dinamiche, non è più necessaria questa modalità complessa di imputazione che risulta viceversa fondamentale nelle versioni precedenti del programma.
Nel caso si dovesse entrare nella cella contenente una Formula matriciale per una modifica (o anche fare clic involontariamente sulla cella) è necessario ripetere sempre il comando CTRL+SHIFT+INVIO per inserire la Formula.

:: Per un approfondimento sulle Funzioni matriciali si rimanda a: Funzioni Matrice com inserire Formule in forma di Matrice

Indice argomenti

[Valter Borsato: 28/01/2021]